/* 
 * Serial RGB LED
 * ------------------
 * Serial commands control the brightness of R,G,B LEDs 
 *
 * Command structure is "#RRGGBB"
 *
 *
 * Created 18 October 2006
 * copyleft 2006 Tod E. Kurt <tod@todbot.com
 * http://todbot.com/
 *
 ** This sketch was modified a bit in order to interface the board with 
    a Mobile Processing sketch runnining on a cellphone.
 */
 
 
 

int redPin   = 9;   // Red LED,   connected to digital pin 9
int greenPin = 11;  // Green LED, connected to digital pin 10
int bluePin  = 10;  // Blue LED,  connected to digital pin 11


byte pinState = 0;
int endbyte = 35;               //end of serial data  
long previousMillis = 0;        // will store last time data was sent to serial port
long interval = 15000;          // interval at which to send data (milliseconds)

// theurl is what the phone will use to connect to a website
// the format is domain,/path/filename.ext -- Note the comma!! and no http://
// make sure to change the server and page path to match your server adddress
char theurl[] = "website.com,/pathtofile/filename.php";


#define slen 64                 // max lenght for the serial string - serial buffer max is 128 bytes    
char serInStr[slen];            // array to hold the incoming serial string bytes
boolean serverinfo = false;     // variable to define initial settings

void setup()  {
  // sets the led pins as output
  pinMode(redPin,   OUTPUT);   
  pinMode(greenPin, OUTPUT);   
  pinMode(bluePin,  OUTPUT);
  
  analogWrite(redPin,   127);   // set them all to mid brightness
  analogWrite(greenPin, 127);   // set them all to mid brightness
  analogWrite(bluePin,  127);   // set them all to mid brightness
  Serial.begin(9600);
}

void loop() {
  // start the count down
  if (millis() - previousMillis > interval) { // if the end has been met
    previousMillis = millis();                // zero the counter
    
    // Send the endbyte so the phone will fetch a page with the rgb code for the led
    Serial.print(endbyte, BYTE); 
    
  } 
  else {   
    // if the count down is still running
    // we just keep watching the serial port
    
    int datalenght = readSerialString();
    // if we get a # on the serial and server info (theurl) has not been sent
    // we need to tell the phone where to send the data 
    
    if (serInStr[0] == (char) endbyte && serverinfo == false) {
      sendserverinfo();  // send the server info
    } 
    else { 
    // if we get anything other than the endbyte and server info has been sent it means the phone is 
    // talking back with the rgb code from the web
    writetoLED(datalenght);
    }
  }
}


int readSerialString () {
  int i=0;
  int c = 0;
  // we wait on the serial port while it is available
  // and not too long 
  while (Serial.available() && i < slen) {
    // delay a little so we give the buffer time to fill up
    delay(500);
    c = Serial.read();
     // the phone sends a ! at the end so we keep that off the string
    if (c !=33) {
      serInStr[i++] = c;
    }
  }
  return i;
}


void sendserverinfo() {
  Serial.print(theurl);
  delay(100);
  Serial.print(endbyte, BYTE); 
  serverinfo = true; 
}


void writetoLED (int i) {
    
   if(i==7 && serInStr[0] == '#') {
   
   long colorVal = strtol(serInStr+1,NULL,16);
   // We have to invert the values here because the pins we control are acting the ground
   int rcolor = (((colorVal&0xff0000)>>16) - 255) * -1;
   int gcolor = (((colorVal&0x00ff00)>>8) - 255) * -1;
   int bcolor = (((colorVal&0x0000ff)>>0) - 255) * -1;
   
    analogWrite(redPin, rcolor );
    analogWrite(greenPin, gcolor );
    analogWrite(bluePin, bcolor );

   }
}